source: libyaml/trunk/configure.ac @ 264

Revision 264, 1.8 KB checked in by xi, 6 years ago (diff)

Another round of API update.

Line 
1# Run `./bootstrap` to generate the "configure" script.
2
3# Define the package version numbers and the bug reporting link.
4m4_define([YAML_MAJOR], 0)
5m4_define([YAML_MINOR], 2)
6m4_define([YAML_PATCH], 0)
7m4_define([YAML_BUGS], [http://pyyaml.org/newticket?component=libyaml])
8
9# Define the libtool version numbers; check the Autobook, Section 11.4.
10# Bump the libtool version numbers using the following algorithm:
11#   if (the current interface has not been changed):
12#       YAML_REVISION += 1
13#   else:
14#       YAML_REVISION = 0
15#       YAML_CURRENT += 1
16#       if (this release is backward compatible with the previous release):
17#           YAML_AGE += 1
18#       else:
19#           YAML_AGE = 0
20m4_define([YAML_RELEASE], 0)
21m4_define([YAML_CURRENT], 2)
22m4_define([YAML_REVISION], 0)
23m4_define([YAML_AGE], 0)
24
25# Initialize autoconf & automake.
26AC_PREREQ(2.59)
27AC_INIT([yaml], [YAML_MAJOR.YAML_MINOR.YAML_PATCH], [YAML_BUGS])
28AC_CONFIG_AUX_DIR([config])
29AC_CONFIG_HEADERS([config.h])
30AM_INIT_AUTOMAKE([1.9 foreign])
31
32# Define substitutions for the libtool version numbers.
33YAML_LT_RELEASE=YAML_RELEASE
34YAML_LT_CURRENT=YAML_CURRENT
35YAML_LT_REVISION=YAML_REVISION
36YAML_LT_AGE=YAML_AGE
37AC_SUBST(YAML_LT_RELEASE)
38AC_SUBST(YAML_LT_CURRENT)
39AC_SUBST(YAML_LT_REVISION)
40AC_SUBST(YAML_LT_AGE)
41
42# Note: in order to update checks, run `autoscan` and look through "configure.scan".
43
44# Checks for programs.
45AC_PROG_CC
46AC_PROG_CPP
47AC_PROG_INSTALL
48AC_PROG_LN_S
49AC_PROG_MAKE_SET
50AC_PROG_LIBTOOL
51
52AC_CHECK_PROG(DOXYGEN, [doxygen], [true], [false])
53AM_CONDITIONAL(DOXYGEN, [test "$DOXYGEN" = true])
54
55# Checks for header files.
56AC_HEADER_STDC
57AC_CHECK_HEADERS([stdlib.h])
58
59# Checks for typedefs, structures, and compiler characteristics.
60AC_C_CONST
61AC_TYPE_SIZE_T
62
63# Define Makefiles.
64AC_CONFIG_FILES([include/Makefile src/Makefile Makefile tests/Makefile])
65
66# Generate the "configure" script.
67AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.